(* Written by: Nicklaus Wirth (1976)
 * Typed in by Jorge Garcia (3 Feb 1993)
 *)
program knightstour(output);
const n=5; nsq=25;
type index = 1..n;
var i,j: index;
    q: boolean;
    s: set of index;
    a,b: array [1..8] of integer;
    h: array [index, index] of integer;

procedure try(i: integer; x,y: index; var q: boolean);
    var k,u,v: integer; q1: boolean;
begin k := 0;
    repeat k := k+1; q1 := false;
       u := x+a[k]; v := y+b[k];
       if (u in s) and (v in s) then
       if h[u,v] = 0 then
       begin h[u,v] := i;
	   if i<nsq then
	       begin try(i+1,u,v,q1);
		  if not q1 then h[u,v] := 0
               end else q1 := true
       end
    until q1 or (k=8);
    q := q1
end {try};

begin s := [1,2,3,4,5];
    a[1] := 2; b[1] := 1;
    a[2] := 1; b[2] := 2;
    a[3] := -1; b[3] := 2;
    a[4] := -2; b[4] := 1;
    a[5] := -2; b[5] := -1;
    a[6] := -1; b[6] := -2;
    a[7] := 1; b[7] := -2;
    a[8] := 2; b[8] := -1;
    for i := 1 to n do
	for j := 1 to n do h[i,j] := 0;
    h[1,1] := 1; try(2,1,1,q);
    if q then
	for i := 1 to n do
	begin for j := 1 to n do write(h[i,j]:5);
	   writeln
        end
    else writeln('NO SOLUTION')
end.